exception SqlError of Sqlite3.Rc.t

type 'a t = Sqlite3.db
type 'a result = ('a, exn) Result.t

let to_result : Sqlite3.Rc.t -> unit result = function
  | Sqlite3.Rc.OK | Sqlite3.Rc.DONE -> Ok ()
  | res -> Error (SqlError res)

let begin_transaction : Sqlite3.db -> unit result =
 fun db ->
  let query = "BEGIN" in
  Sqlite3.exec db query |> to_result

let commit : Sqlite3.db -> unit result =
 fun db ->
  let query = "COMMIT" in
  Sqlite3.exec db query |> to_result

let rollback : Sqlite3.db -> unit result =
 fun db ->
  let query = "ROLLBACK" in
  Sqlite3.exec db query |> to_result

let savepoint : Sqlite3.db -> string -> unit result =
 fun db name ->
  let query = "SAVEPOINT " ^ name in
  Sqlite3.exec db query |> to_result

let release : Sqlite3.db -> string -> unit result =
 fun db name ->
  let query = "RELEASE SAVEPOINT " ^ name in
  Sqlite3.exec db query |> to_result

let finalize : Sqlite3.stmt -> unit result =
 fun statement -> to_result (Sqlite3.finalize statement)

let reset : Sqlite3.stmt -> unit result =
 fun statement -> to_result (Sqlite3.reset statement)

let of_datatype = function
  | ImportCSV.DataType.Float f -> Sqlite3.Data.FLOAT f
  | ImportCSV.DataType.Integer i -> Sqlite3.Data.INT (Int64.of_int i)
  | ImportCSV.DataType.Null -> Sqlite3.Data.NULL
  | ImportCSV.DataType.Error _ -> Sqlite3.Data.NULL
  | ImportCSV.DataType.Content s -> Sqlite3.Data.TEXT s

let to_datatype : Sqlite3.Data.t -> ImportCSV.DataType.t = function
  | Sqlite3.Data.NONE | Sqlite3.Data.NULL -> ImportCSV.DataType.Null
  | Sqlite3.Data.INT i -> ImportCSV.DataType.Integer (Int64.to_int i)
  | Sqlite3.Data.FLOAT f -> ImportCSV.DataType.Float f
  | Sqlite3.Data.TEXT t | Sqlite3.Data.BLOB t -> ImportCSV.DataType.Content t